Installieren des Funktionsmoduls Z_XTRACT_IS_TABLE auf Ihrem SAP-System

Einleitung

Um die native SAP-Extraktion aus UiPath Process Miningzu verwenden, müssen Sie Ihrem SAP-System das Funktionsmodul Z_XTRACT_IS_TABLE hinzufügen.

Hinweis: Beim Einrichten einer nativen SAP-Extraktion ist das SAP Z_XTRACT_IS_TABLE-Funktionsmodul erforderlich. Wenn beispielsweise das Funktionsmodul in Ihrem SAP-System umbenannt wird, können Sie den richtigen Namen im (optionalen) Parameter FunctionModule in der SAP-Verbindungszeichenfolge angeben.

Voraussetzung

Um das benutzerdefinierte Funktionsmodul auf Ihrem SAP-System installieren zu können, benötigen Sie die Anmeldeinformationen eines SAP-Benutzers mit einem Entwicklungsschlüssel.

Hinzufügen einer neuen Funktionsgruppe

Hinweis: Es wird empfohlen, eine neue Funktionsgruppe hinzuzufügen, um das Funktionsmodul hinzuzufügen.

Führen Sie diese Schritte aus, um eine neue Funktionsgruppe hinzuzufügen.

Schritt	Aktion
1	Öffnen Sie die SAP GUI.
2	Geben Sie SE37 in das Befehlsfeld oben links ein.
3	Gehen Sie zum Menü Gehe zu und wählen Sie Funktionsgruppe -> Gruppe erstellen aus.
4	Geben Sie einen Namen für die Funktionsgruppe ein. Hinweis: Der Name muss mit Z beginnen, z. B. Z_PM_DATA_EXTRACTION .
5	Geben Sie eine Beschreibung für die Funktionsgruppe in das Feld Kurzer Text ein, z. B. ProcessMining-Datenextraktion.
6	Klicken Sie auf SPEICHERN.

Aktivieren der Funktionsgruppe

Führen Sie diese Schritte aus, um die Funktionsgruppe zu aktivieren.

Schritt	Aktion
1	Wählen Sie Funktionsgruppe aus.
2	Suchen Sie nach der von Ihnen erstellten Funktionsgruppe, z. B. PM_DATA_EXTRACTION .
3	Klicken Sie mit der rechten Maustaste auf das oberste Objekt der Gruppe Funktion und wählen Sie Aktivieren aus dem Kontextmenü aus.

Hinzufügen des Funktionsmoduls

Sobald die Funktionsgruppe erstellt wurde, können Sie das Funktionsmodul über das SE37 GUI-Fenster hinzufügen.

Führen Sie diese Schritte aus, um das Funktionsmodul Z_XTRACT_IS_TABLE zu installieren.

Schritt	Aktion
1	Geben Sie Z_XTRACT_IS_TABLE in das Feld Funktionsmodul ein und klicken Sie auf Erstellen.
2	Wechseln Sie zur Registerkarte Attribute und wählen Sie die Option Remote-aktiviertes Modul in der Optionsliste Verarbeitungstyp aus.
3	Wechseln Sie zur Registerkarte Import und definieren Sie die Importparameter wie unten aufgeführt. Hinweis: Möglicherweise erhalten Sie eine Warnung, dass der Operator LIKE veraltet ist. Sie können die Warnung ignorieren und die Liste durchgehen. Klicken Sie auf die EINGABETASTE, um zu bestätigen, dass Sie sie weiterhin verwenden möchten. Sobald Sie die gesamte Liste durchgegangen sind, wird der Code akzeptiert.
4	Wechseln Sie zur Registerkarte Tabellen und definieren Sie die Tabellenparameter wie unten aufgeführt. Hinweis: Möglicherweise erhalten Sie eine Warnung, dass der Operator LIKE veraltet ist. Sie können die Warnung ignorieren und die Liste durchgehen. Klicken Sie auf die EINGABETASTE, um zu bestätigen, dass Sie sie weiterhin verwenden möchten. Sobald Sie die gesamte Liste durchgegangen sind, wird der Code akzeptiert.
5	Wechseln Sie zur Registerkarte Ausnahmen , um die Ausnahmen wie unten aufgeführt zu definieren.
6	Wechseln Sie zur Registerkarte Quellcode und geben Sie den ABAP -Code für Z_XTRACT_IS_TABLE ein. Hinweis: Sie können den unten angezeigten Code kopieren und einfügen.
7	Speichern Sie das Funktionsmodul und aktivieren Sie es.

Parameter importieren

In der Abbildung unten finden Sie eine Übersicht über die Importparameter, die auf der Registerkarte „ Import “ definiert werden müssen.

Tabellenparameter

In der folgenden Abbildung finden Sie eine Übersicht über die Tabellenparameter, die auf der Registerkarte Tabellen zu definieren sind.

Ausnahmen

In der Abbildung unten finden Sie eine Übersicht über die Ausnahmen, die auf der Registerkarte Ausnahmen definiert werden können.

ABAP-Code

Im Codetext unten finden Sie den ABAP-Code, der auf der Registerkarte Quellcode eingefügt werden soll.

FUNCTION Z_XTRACT_IS_TABLE.
*"
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(QUERY_TABLE) LIKE  DD02L-TABNAME
*"     VALUE(DELIMITER) LIKE  SONV-FLAG DEFAULT SPACE
*"     VALUE(NO_DATA) LIKE  SONV-FLAG DEFAULT SPACE
*"    VALUE(ROWSKIPS) LIKE  SOID-ACCNT DEFAULT 0
*"     VALUE(ROWCOUNT) LIKE  SOID-ACCNT DEFAULT 0
*"  TABLES
*"      OPTIONS STRUCTURE  RFC_DB_OPT
*"      FIELDS STRUCTURE  RFC_DB_FLD
*"     DATA STRUCTURE  CHAR8000
*"  EXCEPTIONS
*"      TABLE_NOT_AVAILABLE
*"      TABLE_WITHOUT_DATA
*"     OPTION_NOT_VALID
*"     FIELD_NOT_VALID
*"     NOT_AUTHORIZED
*"      DATA_BUFFER_EXCEEDED
*"-------------------------------------------
"
CALL FUNCTION 'VIEW_AUTHORITY_CHECK'
     EXPORTING
          VIEW_ACTION                    = 'S'
          VIEW_NAME                      = QUERY_TABLE
     EXCEPTIONS
          NO_AUTHORITY                   = 2
          NO_CLIENTINDEPENDENT_AUTHORITY = 2
          NO_LINEDEPENDENT_AUTHORITY     = 2
          OTHERS                         = 1.
IF SY-SUBRC = 2.
  RAISE NOT_AUTHORIZED.
ELSEIF SY-SUBRC = 1.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
* -------------------------------------------- 
*  find out about the structure of QUERY_TABLE
* --------------------------------------------
DATA BEGIN OF TABLE_STRUCTURE OCCURS 10.
        INCLUDE STRUCTURE DFIES.
DATA END OF TABLE_STRUCTURE.
"DATA TABLE_HEADER LIKE X030L.
DATA TABLE_TYPE TYPE DD02V-TABCLASS.
CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    TABNAME              = QUERY_TABLE
*   FIELDNAME            = ' '
*   LANGU                = SY-LANGU
*   LFIELDNAME           = ' '
*   ALL_TYPES            = ' '
*   GROUP_NAMES          = ' '
  IMPORTING
*   X030L_WA             =
    DDOBJTYPE            = TABLE_TYPE
*   DFIES_WA             =
*   LINES_DESCR          =
  TABLES
    DFIES_TAB            = TABLE_STRUCTURE
*   FIXED_VALUES         =
  EXCEPTIONS
    NOT_FOUND            = 1
    INTERNAL_ERROR       = 2
    OTHERS               = 3
          .
IF SY-SUBRC <> 0.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
IF TABLE_TYPE = 'INTTAB'.
  RAISE TABLE_WITHOUT_DATA.
ENDIF.
* -------------------------------------------
*  isolate first field of DATA as output field
*  (i.e. allow for changes to structure DATA!)
* -------------------------------------------
DATA LINE_LENGTH TYPE I.
FIELD-SYMBOLS <D>.
ASSIGN COMPONENT 0 OF STRUCTURE DATA TO <D>.
* If this line leads to a syntax error
* please just delete the 'in character mode'
DESCRIBE FIELD <D> LENGTH LINE_LENGTH in character mode.
* -------------------------------------------
*  if FIELDS are not specified, read all available fields
* -------------------------------------------
DATA NUMBER_OF_FIELDS TYPE I.
DESCRIBE TABLE FIELDS LINES NUMBER_OF_FIELDS.
IF NUMBER_OF_FIELDS = 0.
  LOOP AT TABLE_STRUCTURE.
    MOVE TABLE_STRUCTURE-FIELDNAME TO FIELDS-FIELDNAME.
    APPEND FIELDS.
  ENDLOOP.
ENDIF.
* -------------------------------------------
*  for each field which has to be read, copy structure information
*  into tables FIELDS_INT (internal use) and FIELDS (output)
* -------------------------------------------
DATA: BEGIN OF FIELDS_INT OCCURS 10,
        FIELDNAME  LIKE TABLE_STRUCTURE-FIELDNAME,
        TYPE       LIKE TABLE_STRUCTURE-INTTYPE,
        DECIMALS   LIKE TABLE_STRUCTURE-DECIMALS,
        LENGTH_SRC LIKE TABLE_STRUCTURE-INTLEN,
        LENGTH_DST LIKE TABLE_STRUCTURE-LENG,
        OFFSET_SRC LIKE TABLE_STRUCTURE-OFFSET,
        OFFSET_DST LIKE TABLE_STRUCTURE-OFFSET,
      END OF FIELDS_INT,
      LINE_CURSOR TYPE I.
LINE_CURSOR = 0.
*  for each field which has to be read ...
LOOP AT FIELDS.
  READ TABLE TABLE_STRUCTURE WITH KEY FIELDNAME = FIELDS-FIELDNAME.
  IF SY-SUBRC NE 0.
    RAISE FIELD_NOT_VALID.
  ENDIF.
* compute the place for field contents in DATA rows:
* if not first field in row, allow space for delimiter
  IF LINE_CURSOR <> 0.
    IF NO_DATA EQ SPACE AND DELIMITER NE SPACE.
      MOVE DELIMITER TO DATA+LINE_CURSOR.
    ENDIF.
    LINE_CURSOR = LINE_CURSOR + STRLEN( DELIMITER ).
  ENDIF.
* ... copy structure information into tables FIELDS_INT
* (which is used internally during SELECT) ...
  FIELDS_INT-FIELDNAME  = TABLE_STRUCTURE-FIELDNAME.
  FIELDS_INT-LENGTH_SRC = TABLE_STRUCTURE-INTLEN.
*  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-OUTPUTLEN.
  FIELDS_INT-OFFSET_SRC = TABLE_STRUCTURE-OFFSET.
  FIELDS_INT-OFFSET_DST = LINE_CURSOR.
  FIELDS_INT-TYPE       = TABLE_STRUCTURE-INTTYPE.
  FIELDS_INT-DECIMALS   = TABLE_STRUCTURE-DECIMALS.
* compute the place for contents of next field in DATA rows
*  LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-OUTPUTLEN.
  IF LINE_CURSOR > LINE_LENGTH AND NO_DATA EQ SPACE.
    RAISE DATA_BUFFER_EXCEEDED.
  ENDIF.
  APPEND FIELDS_INT.
* ... and into table FIELDS (which is output to the caller)
  FIELDS-FIELDTEXT = TABLE_STRUCTURE-FIELDTEXT.
  FIELDS-TYPE      = TABLE_STRUCTURE-INTTYPE.
  FIELDS-LENGTH    = FIELDS_INT-LENGTH_DST.
  FIELDS-OFFSET    = FIELDS_INT-OFFSET_DST.
  MODIFY FIELDS.
ENDLOOP.
* end of loop at FIELDS
* -------------------------------------------
*  read data from the database and copy relevant portions into DATA
* -------------------------------------------
* output data only if NO_DATA equals space (otherwise the structure
* information in FIELDS is the only result of the module)
IF NO_DATA EQ SPACE.
DATA: BEGIN OF WORK, BUFFER(30000), F TYPE F, END OF WORK.
FIELD-SYMBOLS: <WA> TYPE ANY, <COMP> TYPE ANY.
ASSIGN WORK TO <WA> CASTING TYPE (QUERY_TABLE).
IF ROWCOUNT > 0.
  ROWCOUNT = ROWCOUNT + ROWSKIPS.
ENDIF.
  SELECT * FROM (QUERY_TABLE) INTO <WA> WHERE (OPTIONS).
    IF SY-DBCNT GT ROWSKIPS.
*   copy all relevant fields into DATA (output) table
      LOOP AT FIELDS_INT.
        IF FIELDS_INT-TYPE = 'P'.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE
            DECIMALS FIELDS_INT-DECIMALS.
        ELSE.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE.
        ENDIF.
        MOVE <COMP> TO
            <D>+FIELDS_INT-OFFSET_DST(FIELDS_INT-LENGTH_DST).
      ENDLOOP.
*   end of loop at FIELDS_INT
      APPEND DATA.
      IF ROWCOUNT > 0 AND SY-DBCNT GE ROWCOUNT. EXIT. ENDIF.
    ENDIF.
  ENDSELECT.
ENDIF.
ENDFUNCTION.

Überprüfen und Aktivieren des Funktionsmoduls

Nachdem Sie den ABAP-Code eingefügt haben, sollten Sie Ihren Code auf Syntaxfehler überprüfen, bevor Sie das Funktionsmodul aktivieren.

Überprüfen des Funktionsmoduls

Führen Sie diesen Schritt aus, um den ABAP-Code zu überprüfen.

Schritt	Aktion
1	Drücken CTRL+F2 auf der Registerkarte SAP -Quellcode .

Wenn keine Fehler vorliegen, können Sie den Funktionsbaustein aktivieren.

Aktivieren des Funktionsmoduls

Führen Sie diese Schritte aus, um das Funktionsmodul zu aktivieren.

Schritt	Aktion
1	Geben Sie SE80 in das Befehlsfeld oben links ein.
2	Wählen Sie Funktionsmodul aus.
3	Suchen Sie nach Z_XTRACT_IS_TABLE .
4	Klicken Sie mit der rechten Maustaste auf das oberste Objekt von Z_XTRACT_IS_TABLE und wählen Aktivieren aus dem Kontextmenü aus.

Herstellen einer Verbindung mit der SAP-Datenquelle über UiPath Process Mining

An diesem Punkt ist es möglich, Daten mithilfe der nativen SAP-Verbindung aus dem SAP-System zu extrahieren. Sie können eine Verbindung mit der SAP-Datenquelle herstellen, indem Sie eine neue Eingabetabelle mithilfe einer SAP-Verbindungszeichenfolgentabelle erstellen und eine Abfrage zum Extrahieren der Daten definieren. Siehe Abbildung unten.