Installation du module de fonction Z_XTRACT_IS_TABLE sur votre système SAP

Introduction

Pour utiliser l'extraction SAP native d' UiPath Process Mining, vous devez ajouter le module Fonction Z_XTRACT_IS_TABLE à votre système SAP.

Remarque :

Lors de la configuration d’une extraction SAP native, le module de fonction SAP Z_XTRACT_IS_TABLE est nécessaire. Si, par exemple, le module de fonction est renommé dans votre système SAP, vous pouvez spécifier le nom correct dans le paramètre FunctionModule (facultatif) de la chaîne de connexion SAP.

Prérequis

Pour pouvoir installer le module de fonction personnalisée sur votre système SAP, vous devez disposer des informations d'identification d'un utilisateur SAP avec une clé de développement.

Ajout d'un nouveau groupe de fonctions

Remarque :

Il est recommandé d'ajouter un nouveau groupe de fonctions pour ajouter le module de fonction.

Suivez ces étapes pour ajouter un groupe de fonctions.

Étape	Action
1	Ouvrez SAP GUI.
2	Saisissez SE37 dans le champ de commande en haut à gauche.
3	Accédez au menu Aller à et sélectionnez Groupe de fonctions -> Créer un groupe .
4	Saisissez un nom pour le groupe de fonctions. Remarque : le nom doit commencer par Z , par exemple Z_PM_DATA_EXTRACTION .
5	Saisissez une description pour le groupe de fonctions dans le champ Texte court , par exemple Extraction de données ProcessMining .
6	Cliquez sur ENREGISTRER (SAVE).

Activation du groupe de fonctions

Suivez ces étapes pour activer le groupe Function.

Étape	Action
1	Sélectionnez Groupe de fonctions.
2	Recherchez le groupe de fonctions que vous avez créé, par exemple PM_DATA_EXTRACTION .
3	Cliquez avec le bouton droit sur l'objet supérieur du groupe de fonctions et sélectionnez l'activer dans le menu contextuel.

Ajout du module de fonction

Une fois le groupe de fonctions créé, vous pouvez ajouter le module de fonction à partir de la fenêtre GUI SE37.

Suivez ces étapes pour installer le module de fonction Z_XTRACT_IS_TABLE.

Étape	Action
1	Entrez Z_XTRACT_IS_TABLE dans le champ Module de fonction et cliquez sur Créer .
2	Accédez à l'onglet Attributs et sélectionnez l'option Module activé à distance dans la liste des options de Type de traitement .
3	Accédez à l'onglet Importer et définissez les paramètres d'importation comme indiqué ci-dessous. Remarque : vous pourriez recevoir un avertissement indiquant que l'opérateur LIKE est obsolète. Vous pouvez ignorer l'avertissement et parcourir la liste. Cliquez sur ENTREZ pour confirmer que vous souhaitez toujours l'utiliser. Une fois que vous avez parcouru la liste entière, le code est accepté.
4	Accédez à l'onglet Tables et définissez les paramètres des tables comme indiqué ci-dessous. Remarque : vous pourriez recevoir un avertissement indiquant que l'opérateur LIKE est obsolète. Vous pouvez ignorer l'avertissement et parcourir la liste. Cliquez sur ENTREZ pour confirmer que vous souhaitez toujours l'utiliser. Une fois que vous avez parcouru la liste entière, le code est accepté.
5	Accédez à l'onglet Exceptions pour définir les exceptions comme indiqué ci-dessous.
6	Accédez à l'onglet Code source et saisissez le code ABAP pour le Z_XTRACT_IS_TABLE . Remarque : vous pouvez copier et coller le code affiché ci-dessous.
7	Enregistrez le module Function et activez-le.

Importer les paramètres

Voir l'illustration ci-dessous pour un aperçu des paramètres d'importation à définir dans l'onglet Importer .

Paramètres des tables

Voir l'illustration ci-dessous pour un aperçu des paramètres des tables à définir dans l'onglet Tables (Tables).

Exceptions

Voir l'illustration ci-dessous pour un aperçu des exceptions à définir dans l'onglet Exceptions .

Code ABAP

Voir le texte du code ci-dessous pour le code ABAP à coller dans l'onglet Code source .

FUNCTION Z_XTRACT_IS_TABLE.
*"
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(QUERY_TABLE) LIKE  DD02L-TABNAME
*"     VALUE(DELIMITER) LIKE  SONV-FLAG DEFAULT SPACE
*"     VALUE(NO_DATA) LIKE  SONV-FLAG DEFAULT SPACE
*"    VALUE(ROWSKIPS) LIKE  SOID-ACCNT DEFAULT 0
*"     VALUE(ROWCOUNT) LIKE  SOID-ACCNT DEFAULT 0
*"  TABLES
*"      OPTIONS STRUCTURE  RFC_DB_OPT
*"      FIELDS STRUCTURE  RFC_DB_FLD
*"     DATA STRUCTURE  CHAR8000
*"  EXCEPTIONS
*"      TABLE_NOT_AVAILABLE
*"      TABLE_WITHOUT_DATA
*"     OPTION_NOT_VALID
*"     FIELD_NOT_VALID
*"     NOT_AUTHORIZED
*"      DATA_BUFFER_EXCEEDED
*"-------------------------------------------
"
CALL FUNCTION 'VIEW_AUTHORITY_CHECK'
     EXPORTING
          VIEW_ACTION                    = 'S'
          VIEW_NAME                      = QUERY_TABLE
     EXCEPTIONS
          NO_AUTHORITY                   = 2
          NO_CLIENTINDEPENDENT_AUTHORITY = 2
          NO_LINEDEPENDENT_AUTHORITY     = 2
          OTHERS                         = 1.
IF SY-SUBRC = 2.
  RAISE NOT_AUTHORIZED.
ELSEIF SY-SUBRC = 1.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
* -------------------------------------------- 
*  find out about the structure of QUERY_TABLE
* --------------------------------------------
DATA BEGIN OF TABLE_STRUCTURE OCCURS 10.
        INCLUDE STRUCTURE DFIES.
DATA END OF TABLE_STRUCTURE.
"DATA TABLE_HEADER LIKE X030L.
DATA TABLE_TYPE TYPE DD02V-TABCLASS.
CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    TABNAME              = QUERY_TABLE
*   FIELDNAME            = ' '
*   LANGU                = SY-LANGU
*   LFIELDNAME           = ' '
*   ALL_TYPES            = ' '
*   GROUP_NAMES          = ' '
  IMPORTING
*   X030L_WA             =
    DDOBJTYPE            = TABLE_TYPE
*   DFIES_WA             =
*   LINES_DESCR          =
  TABLES
    DFIES_TAB            = TABLE_STRUCTURE
*   FIXED_VALUES         =
  EXCEPTIONS
    NOT_FOUND            = 1
    INTERNAL_ERROR       = 2
    OTHERS               = 3
          .
IF SY-SUBRC <> 0.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
IF TABLE_TYPE = 'INTTAB'.
  RAISE TABLE_WITHOUT_DATA.
ENDIF.
* -------------------------------------------
*  isolate first field of DATA as output field
*  (i.e. allow for changes to structure DATA!)
* -------------------------------------------
DATA LINE_LENGTH TYPE I.
FIELD-SYMBOLS <D>.
ASSIGN COMPONENT 0 OF STRUCTURE DATA TO <D>.
* If this line leads to a syntax error
* please just delete the 'in character mode'
DESCRIBE FIELD <D> LENGTH LINE_LENGTH in character mode.
* -------------------------------------------
*  if FIELDS are not specified, read all available fields
* -------------------------------------------
DATA NUMBER_OF_FIELDS TYPE I.
DESCRIBE TABLE FIELDS LINES NUMBER_OF_FIELDS.
IF NUMBER_OF_FIELDS = 0.
  LOOP AT TABLE_STRUCTURE.
    MOVE TABLE_STRUCTURE-FIELDNAME TO FIELDS-FIELDNAME.
    APPEND FIELDS.
  ENDLOOP.
ENDIF.
* -------------------------------------------
*  for each field which has to be read, copy structure information
*  into tables FIELDS_INT (internal use) and FIELDS (output)
* -------------------------------------------
DATA: BEGIN OF FIELDS_INT OCCURS 10,
        FIELDNAME  LIKE TABLE_STRUCTURE-FIELDNAME,
        TYPE       LIKE TABLE_STRUCTURE-INTTYPE,
        DECIMALS   LIKE TABLE_STRUCTURE-DECIMALS,
        LENGTH_SRC LIKE TABLE_STRUCTURE-INTLEN,
        LENGTH_DST LIKE TABLE_STRUCTURE-LENG,
        OFFSET_SRC LIKE TABLE_STRUCTURE-OFFSET,
        OFFSET_DST LIKE TABLE_STRUCTURE-OFFSET,
      END OF FIELDS_INT,
      LINE_CURSOR TYPE I.
LINE_CURSOR = 0.
*  for each field which has to be read ...
LOOP AT FIELDS.
  READ TABLE TABLE_STRUCTURE WITH KEY FIELDNAME = FIELDS-FIELDNAME.
  IF SY-SUBRC NE 0.
    RAISE FIELD_NOT_VALID.
  ENDIF.
* compute the place for field contents in DATA rows:
* if not first field in row, allow space for delimiter
  IF LINE_CURSOR <> 0.
    IF NO_DATA EQ SPACE AND DELIMITER NE SPACE.
      MOVE DELIMITER TO DATA+LINE_CURSOR.
    ENDIF.
    LINE_CURSOR = LINE_CURSOR + STRLEN( DELIMITER ).
  ENDIF.
* ... copy structure information into tables FIELDS_INT
* (which is used internally during SELECT) ...
  FIELDS_INT-FIELDNAME  = TABLE_STRUCTURE-FIELDNAME.
  FIELDS_INT-LENGTH_SRC = TABLE_STRUCTURE-INTLEN.
*  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-OUTPUTLEN.
  FIELDS_INT-OFFSET_SRC = TABLE_STRUCTURE-OFFSET.
  FIELDS_INT-OFFSET_DST = LINE_CURSOR.
  FIELDS_INT-TYPE       = TABLE_STRUCTURE-INTTYPE.
  FIELDS_INT-DECIMALS   = TABLE_STRUCTURE-DECIMALS.
* compute the place for contents of next field in DATA rows
*  LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-OUTPUTLEN.
  IF LINE_CURSOR > LINE_LENGTH AND NO_DATA EQ SPACE.
    RAISE DATA_BUFFER_EXCEEDED.
  ENDIF.
  APPEND FIELDS_INT.
* ... and into table FIELDS (which is output to the caller)
  FIELDS-FIELDTEXT = TABLE_STRUCTURE-FIELDTEXT.
  FIELDS-TYPE      = TABLE_STRUCTURE-INTTYPE.
  FIELDS-LENGTH    = FIELDS_INT-LENGTH_DST.
  FIELDS-OFFSET    = FIELDS_INT-OFFSET_DST.
  MODIFY FIELDS.
ENDLOOP.
* end of loop at FIELDS
* -------------------------------------------
*  read data from the database and copy relevant portions into DATA
* -------------------------------------------
* output data only if NO_DATA equals space (otherwise the structure
* information in FIELDS is the only result of the module)
IF NO_DATA EQ SPACE.
DATA: BEGIN OF WORK, BUFFER(30000), F TYPE F, END OF WORK.
FIELD-SYMBOLS: <WA> TYPE ANY, <COMP> TYPE ANY.
ASSIGN WORK TO <WA> CASTING TYPE (QUERY_TABLE).
IF ROWCOUNT > 0.
  ROWCOUNT = ROWCOUNT + ROWSKIPS.
ENDIF.
  SELECT * FROM (QUERY_TABLE) INTO <WA> WHERE (OPTIONS).
    IF SY-DBCNT GT ROWSKIPS.
*   copy all relevant fields into DATA (output) table
      LOOP AT FIELDS_INT.
        IF FIELDS_INT-TYPE = 'P'.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE
            DECIMALS FIELDS_INT-DECIMALS.
        ELSE.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE.
        ENDIF.
        MOVE <COMP> TO
            <D>+FIELDS_INT-OFFSET_DST(FIELDS_INT-LENGTH_DST).
      ENDLOOP.
*   end of loop at FIELDS_INT
      APPEND DATA.
      IF ROWCOUNT > 0 AND SY-DBCNT GE ROWCOUNT. EXIT. ENDIF.
    ENDIF.
  ENDSELECT.
ENDIF.
ENDFUNCTION.

Vérification et activation du module de fonction

Après avoir collé le code ABAP, il est recommandé de vérifier que votre code ne contient pas d'erreurs de syntaxe avant d'activer le module Fonction.

Vérification du module de fonction

Suivez cette étape pour vérifier le code ABAP.

Étape	Action
1	Appuyez sur CTRL+F2 dans l'onglet Code source SAP.

S'il n'y a pas d'erreurs, vous pouvez activer le module Fonction.

Activation du module de fonction

Suivez ces étapes pour activer le module Function.

Étape	Action
1	Saisissez SE80 dans le champ de commande en haut à gauche.
2	Sélectionnez le module de fonction.
3	Recherchez Z_XTRACT_IS_TABLE .
4	Cliquez avec le bouton droit sur l'objet supérieur de Z_XTRACT_IS_TABLE et sélectionnez l'activer dans le menu contextuel.

Connexion à la source de données SAP à partir d'UiPath Process Mining

À ce stade, il est possible d'extraire des données du système SAP à l'aide de la connexion SAP native. Vous pouvez vous connecter à la source de données SAP en créant une nouvelle table d'entrée à l'aide d'une table de chaînes de connexion SAP et en définissant une requête pour extraire les données. Voir l'illustration ci-dessous.