Instalando o módulo de função Z_XTRACT_IS_TABLE em seu sistema SAP

Introdução

Para usar a extração SAP nativa do UiPath Process Mining, você deve adicionar o Módulo de função Z_XTRACT_IS_TABLE ao seu sistema SAP.

Observação:

When setting up a native SAP extraction the SAP Z_XTRACT_IS_TABLE Function Module is required. If, for example, the Function Module is renamed in your SAP system, you can specify the correct name in the (optional) FunctionModule parameter in the SAP connection string.

Pré-requisito

Para poder instalar o Custom Function Module em seu sistema SAP, você deve ter as credenciais de um usuário SAP com uma chave de desenvolvimento.

Adicionando um novo grupo de funções

Observação:

É recomendável adicionar um novo grupo de funções para adicionar o módulo de função.

Siga estas etapas para adicionar um novo grupo de funções.

Etapa	Ação
1	Abra a GUI do SAP.
2	Digite SE37 no campo de comando no canto superior esquerdo.
3	Acesse o menu Ir para e selecione Grupo de funções -> Criar grupo .
4	Insira um nome para o grupo Função. Observação: o nome deve começar com Z , por exemplo Z_PM_DATA_EXTRACTION .
5	Insira uma descrição para o Grupo Função no campo Texto curto , por exemplo, Extração de dados do ProcessMining .
6	Clique em SALVAR.

Ativando o Grupo de Funções

Siga estas etapas para ativar o grupo Função.

Etapa	Ação
1	Selecione Grupo de funções.
2	Pesquise o grupo Function que você criou, por exemplo PM_DATA_EXTRACTION.
3	Clique com o botão direito do mouse no objeto superior do grupo Função e selecione Ativá-lo no menu de contexto.

Adicionando o módulo de função

Uma vez que o grupo Function é criado, você pode adicionar o módulo Function na janela SE37 GUI.

Siga estas etapas para instalar o módulo de função Z_XTRACT_IS_TABLE.

Etapa	Ação
1	Insira Z_XTRACT_IS_TABLE no campo Módulo de funções e clique em Criar .
2	Acesse a guia Atributos e selecione a opção Módulo Habilitado Remoto na lista de opções de Tipo de Processamento .
3	Acesse a aba Importar e defina os parâmetros de importação conforme listado abaixo. Observação: você pode receber um aviso de que o operador LIKE está obsoleto. Você pode ignorar o aviso e passar pela lista. Clique em Enter para reconhecer que você ainda deseja usá-lo. Depois de passar por toda a lista, o código é aceito.
4	Acesse a aba Tabelas e defina os parâmetros das tabelas conforme listado abaixo. Observação: você pode receber um aviso de que o operador LIKE está obsoleto. Você pode ignorar o aviso e passar pela lista. Clique em Enter para reconhecer que você ainda deseja usá-lo. Depois de passar por toda a lista, o código é aceito.
5	Acesse a aba Exceções para definir as exceções conforme listado abaixo.
6	Vá para a aba Código-fonte e insira o código ABAP para o Z_XTRACT_IS_TABLE . Observação: você pode copiar e colar o código exibido abaixo.
7	Salve o módulo Function e ative-o.

Importar parâmetros

Consulte a ilustração abaixo para uma visão geral dos parâmetros de importação a serem definidos na guia Importar .

Parâmetros das Tabelas

Consulte a ilustração abaixo para ter uma visão geral dos parâmetros das tabelas a serem definidos na guia Tabelas.

Exceções

Consulte a ilustração abaixo para uma visão geral das Exceções a serem definidas na guia Exceções .

Código ABAP

Veja o texto do código abaixo para o código ABAP ser colado na aba Código-fonte .

FUNCTION Z_XTRACT_IS_TABLE.
*"
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(QUERY_TABLE) LIKE  DD02L-TABNAME
*"     VALUE(DELIMITER) LIKE  SONV-FLAG DEFAULT SPACE
*"     VALUE(NO_DATA) LIKE  SONV-FLAG DEFAULT SPACE
*"    VALUE(ROWSKIPS) LIKE  SOID-ACCNT DEFAULT 0
*"     VALUE(ROWCOUNT) LIKE  SOID-ACCNT DEFAULT 0
*"  TABLES
*"      OPTIONS STRUCTURE  RFC_DB_OPT
*"      FIELDS STRUCTURE  RFC_DB_FLD
*"     DATA STRUCTURE  CHAR8000
*"  EXCEPTIONS
*"      TABLE_NOT_AVAILABLE
*"      TABLE_WITHOUT_DATA
*"     OPTION_NOT_VALID
*"     FIELD_NOT_VALID
*"     NOT_AUTHORIZED
*"      DATA_BUFFER_EXCEEDED
*"-------------------------------------------
"
CALL FUNCTION 'VIEW_AUTHORITY_CHECK'
     EXPORTING
          VIEW_ACTION                    = 'S'
          VIEW_NAME                      = QUERY_TABLE
     EXCEPTIONS
          NO_AUTHORITY                   = 2
          NO_CLIENTINDEPENDENT_AUTHORITY = 2
          NO_LINEDEPENDENT_AUTHORITY     = 2
          OTHERS                         = 1.
IF SY-SUBRC = 2.
  RAISE NOT_AUTHORIZED.
ELSEIF SY-SUBRC = 1.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
* -------------------------------------------- 
*  find out about the structure of QUERY_TABLE
* --------------------------------------------
DATA BEGIN OF TABLE_STRUCTURE OCCURS 10.
        INCLUDE STRUCTURE DFIES.
DATA END OF TABLE_STRUCTURE.
"DATA TABLE_HEADER LIKE X030L.
DATA TABLE_TYPE TYPE DD02V-TABCLASS.
CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    TABNAME              = QUERY_TABLE
*   FIELDNAME            = ' '
*   LANGU                = SY-LANGU
*   LFIELDNAME           = ' '
*   ALL_TYPES            = ' '
*   GROUP_NAMES          = ' '
  IMPORTING
*   X030L_WA             =
    DDOBJTYPE            = TABLE_TYPE
*   DFIES_WA             =
*   LINES_DESCR          =
  TABLES
    DFIES_TAB            = TABLE_STRUCTURE
*   FIXED_VALUES         =
  EXCEPTIONS
    NOT_FOUND            = 1
    INTERNAL_ERROR       = 2
    OTHERS               = 3
          .
IF SY-SUBRC <> 0.
  RAISE TABLE_NOT_AVAILABLE.
ENDIF.
IF TABLE_TYPE = 'INTTAB'.
  RAISE TABLE_WITHOUT_DATA.
ENDIF.
* -------------------------------------------
*  isolate first field of DATA as output field
*  (i.e. allow for changes to structure DATA!)
* -------------------------------------------
DATA LINE_LENGTH TYPE I.
FIELD-SYMBOLS <D>.
ASSIGN COMPONENT 0 OF STRUCTURE DATA TO <D>.
* If this line leads to a syntax error
* please just delete the 'in character mode'
DESCRIBE FIELD <D> LENGTH LINE_LENGTH in character mode.
* -------------------------------------------
*  if FIELDS are not specified, read all available fields
* -------------------------------------------
DATA NUMBER_OF_FIELDS TYPE I.
DESCRIBE TABLE FIELDS LINES NUMBER_OF_FIELDS.
IF NUMBER_OF_FIELDS = 0.
  LOOP AT TABLE_STRUCTURE.
    MOVE TABLE_STRUCTURE-FIELDNAME TO FIELDS-FIELDNAME.
    APPEND FIELDS.
  ENDLOOP.
ENDIF.
* -------------------------------------------
*  for each field which has to be read, copy structure information
*  into tables FIELDS_INT (internal use) and FIELDS (output)
* -------------------------------------------
DATA: BEGIN OF FIELDS_INT OCCURS 10,
        FIELDNAME  LIKE TABLE_STRUCTURE-FIELDNAME,
        TYPE       LIKE TABLE_STRUCTURE-INTTYPE,
        DECIMALS   LIKE TABLE_STRUCTURE-DECIMALS,
        LENGTH_SRC LIKE TABLE_STRUCTURE-INTLEN,
        LENGTH_DST LIKE TABLE_STRUCTURE-LENG,
        OFFSET_SRC LIKE TABLE_STRUCTURE-OFFSET,
        OFFSET_DST LIKE TABLE_STRUCTURE-OFFSET,
      END OF FIELDS_INT,
      LINE_CURSOR TYPE I.
LINE_CURSOR = 0.
*  for each field which has to be read ...
LOOP AT FIELDS.
  READ TABLE TABLE_STRUCTURE WITH KEY FIELDNAME = FIELDS-FIELDNAME.
  IF SY-SUBRC NE 0.
    RAISE FIELD_NOT_VALID.
  ENDIF.
* compute the place for field contents in DATA rows:
* if not first field in row, allow space for delimiter
  IF LINE_CURSOR <> 0.
    IF NO_DATA EQ SPACE AND DELIMITER NE SPACE.
      MOVE DELIMITER TO DATA+LINE_CURSOR.
    ENDIF.
    LINE_CURSOR = LINE_CURSOR + STRLEN( DELIMITER ).
  ENDIF.
* ... copy structure information into tables FIELDS_INT
* (which is used internally during SELECT) ...
  FIELDS_INT-FIELDNAME  = TABLE_STRUCTURE-FIELDNAME.
  FIELDS_INT-LENGTH_SRC = TABLE_STRUCTURE-INTLEN.
*  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
  FIELDS_INT-LENGTH_DST = TABLE_STRUCTURE-OUTPUTLEN.
  FIELDS_INT-OFFSET_SRC = TABLE_STRUCTURE-OFFSET.
  FIELDS_INT-OFFSET_DST = LINE_CURSOR.
  FIELDS_INT-TYPE       = TABLE_STRUCTURE-INTTYPE.
  FIELDS_INT-DECIMALS   = TABLE_STRUCTURE-DECIMALS.
* compute the place for contents of next field in DATA rows
*  LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-LENG.
* modified by Theobald, 2007-11-20
LINE_CURSOR = LINE_CURSOR + TABLE_STRUCTURE-OUTPUTLEN.
  IF LINE_CURSOR > LINE_LENGTH AND NO_DATA EQ SPACE.
    RAISE DATA_BUFFER_EXCEEDED.
  ENDIF.
  APPEND FIELDS_INT.
* ... and into table FIELDS (which is output to the caller)
  FIELDS-FIELDTEXT = TABLE_STRUCTURE-FIELDTEXT.
  FIELDS-TYPE      = TABLE_STRUCTURE-INTTYPE.
  FIELDS-LENGTH    = FIELDS_INT-LENGTH_DST.
  FIELDS-OFFSET    = FIELDS_INT-OFFSET_DST.
  MODIFY FIELDS.
ENDLOOP.
* end of loop at FIELDS
* -------------------------------------------
*  read data from the database and copy relevant portions into DATA
* -------------------------------------------
* output data only if NO_DATA equals space (otherwise the structure
* information in FIELDS is the only result of the module)
IF NO_DATA EQ SPACE.
DATA: BEGIN OF WORK, BUFFER(30000), F TYPE F, END OF WORK.
FIELD-SYMBOLS: <WA> TYPE ANY, <COMP> TYPE ANY.
ASSIGN WORK TO <WA> CASTING TYPE (QUERY_TABLE).
IF ROWCOUNT > 0.
  ROWCOUNT = ROWCOUNT + ROWSKIPS.
ENDIF.
  SELECT * FROM (QUERY_TABLE) INTO <WA> WHERE (OPTIONS).
    IF SY-DBCNT GT ROWSKIPS.
*   copy all relevant fields into DATA (output) table
      LOOP AT FIELDS_INT.
        IF FIELDS_INT-TYPE = 'P'.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE
            DECIMALS FIELDS_INT-DECIMALS.
        ELSE.
        ASSIGN COMPONENT FIELDS_INT-FIELDNAME
            OF STRUCTURE <WA> TO <COMP>
            TYPE     FIELDS_INT-TYPE.
        ENDIF.
        MOVE <COMP> TO
            <D>+FIELDS_INT-OFFSET_DST(FIELDS_INT-LENGTH_DST).
      ENDLOOP.
*   end of loop at FIELDS_INT
      APPEND DATA.
      IF ROWCOUNT > 0 AND SY-DBCNT GE ROWCOUNT. EXIT. ENDIF.
    ENDIF.
  ENDSELECT.
ENDIF.
ENDFUNCTION.

Verificando e Ativando o Módulo de Função

Depois de colar o código ABAP, é recomendável verificar se há erros de sintaxe no código antes de ativar o módulo Função.

Verificação do Módulo de funções

Siga esta etapa para verificar o código ABAP.

Etapa	Ação
1	Pressione CTRL+F2 na aba Código-fonte do SAP.

Se não houver erros, você pode ativar o módulo Function.

Ativação do Módulo de funções

Siga estas etapas para ativar o Módulo de funções.

Etapa	Ação
1	Digite SE80 no campo de comando no canto superior esquerdo.
2	Selecione Módulo de funções.
3	Procure por Z_XTRACT_IS_TABLE.
4	Clique com o botão direito do mouse no objeto superior de Z_XTRACT_IS_TABLE e selecione Ativá-lo no menu de contexto.

Conectando-se à fonte de dados SAP do UiPath Process Mining

Neste ponto é possível extrair dados do sistema SAP utilizando a conexão SAP nativa. Você pode se conectar à fonte de dados SAP criando uma nova tabela de entrada usando uma tabela de string de conexão SAP e definindo uma consulta para extrair os dados. Veja a ilustração abaixo.